Excelの全ワークシート名を一覧化！使えるVBAマクロを紹介

Excelブック内の全てのワークシート名を一覧化したいと思ったことはありませんか？今回は、そんなニーズに応えるVBAマクロの紹介をします。

このマクロができること
マクロのVBAコード
マクロ実行の手順
注意点
まとめ

このマクロができること

ブック内のすべてのワークシート名を一覧化し、選択したセルの位置からリストアップ
各シートが表示状態かどうかも合わせて出力

マクロのVBAコード

以下のコードをVBE(Altキー+F11キーで起動)の標準モジュールへ貼り付けてください(挿入→標準モジュール)。

Sub ExportSheetData()
    Dim sht As Object
    Dim startCell As Range
    Dim originalSelection As Range
    Dim nextRow As Long
    Dim response As VbMsgBoxResult
    ' もともと選択していたセル・範囲を記憶
    Set originalSelection = Selection
    'セルの指定
    On Error Resume Next
    Set startCell = Application.InputBox("シート名の起点となるセルを選択してください", Default:=originalSelection.Address, Type:=8).Cells(1, 1)
    On Error GoTo 0
    'セル指定がキャンセルされた場合、終了
    If startCell Is Nothing Then Exit Sub
    '確認メッセージ
    response = MsgBox("このセルより2列分、下の行がすべて削除されますが書き出してもよいですか？", vbOKCancel)
    If response = vbCancel Then Exit Sub
    'ヘッダーの書き出し
    startCell.Value = "Name"
    startCell.Offset(0, 1).Value = "Visible"
    '次の行への書き出しの準備
    nextRow = startCell.Row + 1
    'シートの情報を書き出し
    For Each sht In ThisWorkbook.Sheets
        startCell.Worksheet.Cells(nextRow, startCell.Column).Value = "'" & sht.Name
        startCell.Worksheet.Cells(nextRow, startCell.Column + 1).Value = "'" & CStr(sht.Visible = xlSheetVisible)
        nextRow = nextRow + 1
    Next sht
    originalSelection.Select
End Sub

マクロ実行の手順

マクロをVBAエディタに取り込みます(標準モジュールへ挿入)。
Excel上でマクロを実行するセルを選択します。ExportSheetDataマクロを実行します(Altキー+F8キーでマクロリストが表示されるので選んで実行)。
マクロを実行すると、起点となるセルを指定するインプットボックスが表示されます。
実行時注意が表示されます。
セルを指定し、「OK」をクリックすると、ブック内の全ワークシート名とその表示状態が一覧化されます。非表示シートの場合は「Visible」列が「False」となります。